#!/opt/vdops/bin/perl

# This script automates the process of initiating the 'calibration' test

# V      Who       When        What
# ---------------------------------------------------------------------------
# 1.8.0  skendric  02-21-2011  Upgrade to Netops 1.4.0
# 1.7.1  skendric  06-25-2010  Allow $error{$target} to be undef
# 1.7.0  skendric  03-30-2010  Upgrade to perl 5.10.1
# 1.6.0  skendric  12-23-2009  Remove Net::SNMP support
# 1.5.4  skendric  03-21-2007  Stylistic mods
# 1.5.3  skendric  11-16-2006  Replace Object Values with OIDs
# 1.5.2  skendric  11-05-2005  Upgrade to new WI::VDOPS module structure
# 1.5.1  skendric  07-04-2005  Fix parameters to snmpSet in do_the_work
# 1.5.0  skendric  05-09-2005  Support Netops.pm-1.2
# 1.4.0  skendric  05-10-2004  Migrate common functions to Netops.pm
# 1.3.0  skendric  04-30-2004  Enhance command-line options
# 1.2.2  skendric  11-16-2003  Use Net::Ping::External
# 1.2.1  skendric  08-10-2003  Minor bug fixes
# 1.2.0  skendric  03-16-2003  Tighted scoping, changed DEBUG to $debug
# 1.1.1  skendric  12-12-2002  Fixed write string bug in info_before
# 1.1.0  skendric  11-17-2002  Added @version, improved build_target()
# 1.0.0  skendric  10-24-2002  First Version
#

# Author:  Stuart Kendrick, sbk {put at sign here} skendric {put dot here} com
#
# Source:  http://www.skendric.com/device
#
# This software is available under the GNU GENERAL PUBLIC LICENSE, see
# http://www.fsf.org/licenses/gpl.html
#

#
# This script takes the following approach:
#     -Parses the hosts table for a list of targets (or accepts a command-
#      line list)
#     -Sets the 'upsAdvTestRuntimeCalibration' variable to 2
#     -Pings them and reports on any which did not survive
#
# Requirements:
#     -The target(s) must be pingable
#
#     -PERL modules:  the WI::Netops collection
#
#
#
# Assumptions:
#
#
# Tested on: 
#        -APC 9606 Web/SNMP card, AP961x + AP963x Network Management Card,
#         SmartUPS, Symmetra
#        -perl-5.12.2
#        -net-snmp-5.6
#
#
# Instructions:
#       -Customize the script for your site:  find the 'user-configurable
#        variables' section and modify as appropriate
#       -Type "apc-calibrate" to see the command-line options
#       -Try it out
#
#
# Caveats:
#
#
# Known Bugs:
#
#
# To do:
#
#

# Begin script

# Load modules
use strict;
use warnings;
use feature 'say';
use feature 'switch';
use Carp qw(carp cluck croak confess); 
use Data::Dumper;
use English qw( -no_match_vars );
use Getopt::Std;
use WI::Netops::APCTools 1.2.2;
use WI::Netops::HostTools 1.0.4;
use WI::Netops::NetopsTools 2.2.3;
use WI::Netops::NetopsData 1.4.0;
use WI::Netops::PingTools 1.1.7;
use WI::Netops::SNMPTools 1.5.3;
use WI::Netops::Utilities 1.4.4;

# Declare global variables
my %calib_date;          # upsAdvTestCalibrationDate
my %calib_result;        # upsAdvTestCalibrationResults

# Define global variables
$debug = 0;
            # 10 = Logging
            #  9 = Database SELECT operations
            #  8 = Per IP/MAC/Port processing
            #  7 = Database INSERT/UPDATE/DELETE
            #  6 = Dump SNMP var
            #  5 = Dump snmp_packets
            #  4 = Grody:    print big var
            #  3 = Verbose:  print mid var
            #  2 = Simple:   print small var
            #  1 = Basic:    subroutine trace
            #  0 = Disable debugging
$program_name = 'apc-calibrate';
$usage = 'Usage:  apc-calibrate -s {yes|no} [-d {integer}] [-r] [-a | -e {expr} | -f {filename} | target1 target2 target3 ...]';
$version = '1.8.0';


# Grab arguments
getopts('ad:e:f:s:', \%option);     
@target = @ARGV;

# Set mode
if      ($option{r})            { $mode = 'report'      }
elsif   (-t STDIN)              { $mode = 'interactive' }
else                            { $mode = 'batch'       }


### Begin Main Program ###############################################
{

  check_args();                   # Check arguments

  read_config();                  # Read Netops config file

  compile_mibs();                 # Compile MIB files

  build_target();                 # Populate @target
  
  target_check();                 # Look for errors in @target
  
  basic_info();                   # Gather information
  
  sanity_check();                 # Check for major errors

  info_before();                  # Gather more information

  print_before();                 # Tell operator what I will do
  
  do_the_work();                  # Reset devices
  
  info_after();                   # Gather information
  
  print_after();                  # Tell the operator what I did

}
##### End Main Program ###############################################



########################################################################
# Do the work:  upload images
########################################################################
sub do_the_work {

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print 'Initiating calibration...' if $mode eq 'interactive';
  if ($dome) {
    say('');
  }
  else {
    sleep $short;
    say "just kidding";
    return 1;
  }

  # Loop through @target, initiating calibration
  for my $target (@target) {
    my $val;

    # Initiate calibration test
    $val = initiate_apc_calibration($target);
    say "Unable to start calibration for $target" unless (defined $val and $val == 1);

  }

  # Make things look pretty
  say('') if $mode eq 'interactive';

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Gather information after calibration initiation
########################################################################
sub info_after {

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print_it('Pinging targets...');
  sleep $short;

  # Loop through targets, pinging
  TARGET:
  for my $ups (@target) {
    my $val;

    # If we can't ping the target, skip to the next one
    unless (ping_it($ups)) {
      print_it("\nCannot ping $ups");
      $error{$ups} = 'Cannot ping';
      next TARGET;
    }

    # Describe previous calibration event
    say 'Getting upsAdvTestCalibrationDate.0' if $debug > 2;
    $val = snmpGet( {host => $ups, oid => '.1.3.6.1.4.1.318.1.1.1.7.2.7.0'} );
    $calib_date{$ups} = $val;
    say 'Getting upsAdvTestCalibrationResults.0' if $debug > 2;
    $val = snmpGet( {host => $ups, oid => '.1.3.6.1.4.1.318.1.1.1.7.2.6.0'} );
    $calib_result{$ups} = $val;

  }

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Gather information
########################################################################
sub info_before {
  my @remove;

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print_it('Gathering more information...');

  # Loop through targets, gathering information
  for my $target (@target) {

    # Describe previous calibration event
    $calib_date{$target}
        = snmpGet( {host => $target, oid => 'upsAdvTestCalibrationDate.0'} );
    $calib_result{$target}
        = snmpGet( {host => $target, oid => 'upsAdvTestCalibrationResults.0'} );
    
    # Entertain operator
    print $BANG if $mode eq 'interactive';
      
  }   
      
  # Make things look pretty
  say "\n" if $mode eq 'interactive';

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Tell operator what I did
########################################################################
sub print_after {
  my $shit_happens = 0;

  # Debug trace
  trace_location('begin') if $debug;

  # If running from cron, don't print report
  return 1 if $mode eq 'batch';

  say "\n\n\n# Here is what I see";

  # Iterate through @target
  for my $target (@target) {
    log_it("Set variables on $target") if $dome;
    $shit_happens++ if defined $error{$target};
  }

  return 1 unless $mode eq 'interactive';

say('');
print <<EOF;
#
# Current targets look like this
#
# target        Mgmt    UPS Model                Calibrate  Calibrate
#               Card                             Date       Result
--------------- ------  ------------------------ ---------- -------------------
EOF

  for my $target (@target) {
    printf "%-15s %-6s  %-24s %-10s %-20.20s\n",
            $target, $apc_card_model{$target}, $apc_device_model{$target},
            $calib_date{$target}, $calib_result{$target};
  }
  say('');

  # If an error occured, talk about it
  if ($shit_happens > 0) {
      print "\n\n\n\n";
      print <<EOF;
#
# Here are the problems I encountered.  I'm not smart enough to fix
# these; please handle these yourself
#
# target          warning message(s)
--------------- --------------------------------------------------
EOF
    for my $target (@target) {
      if (defined $error{$target}) {
        printf "%-15s %-50s\n", $target, $error{$target};
        log_it("Errors for $target:  $error{$target}");
      }
    }
  }

  # Make things look pretty
  log_it("Ending $PROGRAM_NAME");
  say "Ending $PROGRAM_NAME" if $mode eq 'interactive';

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Tell the operator what I will do
########################################################################
sub print_before {

  # Debug trace
  trace_location('begin') if $debug;

  # If running from cron, don't print report
  return 1 if $mode eq 'batch';

  say('');
  print <<EOF;
#
# Current targets look like this
#
# target        Mgmt    UPS Model               Calibrate  Calibrate
#               Card                            Date       Result
--------------- ------  ----------------------- ---------- --------------------
EOF

  for my $target (@target) {
    printf "%-15s %-6s  %-23.23s %-10.10s %-21.21s\n",
            $target, $apc_card_model{$target}, $apc_device_model{$target},
            $calib_date{$target}, $calib_result{$target};
  }

  say('');
  say('');
  say 'Calibrating devices:';
  say 'I plan to initiate calibration on these devices';
  say('');
  if ($dome) {
    say 'This is the real thing:  I will calibrate devices';
  }
  else {
    say 'This is a dry run, no variables will be set';
  }
  say "Stalling for $long seconds to give you time to cancel ...\n";
  sleep $long;
  say "OK, let's roll\n";

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Sanity check
########################################################################
sub sanity_check {
  my @remove;

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print_it('Sanity check...');

  # Loop through targets, removing non-APC devices
  SANITY:
  for my $target (@target) {
  
    # Identify manufacturer
    unless ($manufacturer{$target} eq "APC") {
      say "\nManufacturer of $target is not APC, ignoring" if $debug;
      push @remove, $target;
      next SANITY;
    }

    # Identify UPS model
    if ($apc_device_model{$target} eq 'unknown') {
      say "\nCannot determine model of $target, ignoring" if $debug;
      push @remove, $target;
      next SANITY;
    }

    # Entertain operator
    print $BANG if $mode eq 'interactive';

  }

  # Make things look pretty
  say "\n" if $mode eq 'interactive';

  # Remove entries which failed checks
  prune_basic(@remove);

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Output help
########################################################################
sub HELP_MESSAGE {
  print <<EOF;

  See $netops_global_config (and $netops_alarm_config if this is an
  xxxx-alarm script) for configuration options

  $usage

    -s asks the question:  are you serious?  If you answer 'no', then 
       the script will run in demo mode, making no changes

    -d specifies debug level (typically 0-9)

    -a instructs the script to filter the hosts table using its internally
       defined suffixes variable to produce a list of targets

    -e requires a regex as its argument, with which the script filters
       the hosts table to produce a list of targets.  Enclose the regex in 
       quotes to protect special characters from the shell

    -f points the script to a file containing the list of targets

    target1 target2 target3 ... is the command-line list of targets you
      have specified, in lieu of the -a, -e, or -f options

EOF

  return 1;
}




########################################################################
# Output version
########################################################################
sub VERSION_MESSAGE {
  say "$program_name v$version";
  return 1;
}