#!/opt/vdops/bin/perl

# This script reports on the status of the UPS chassis

# V      Who       When        What
# ---------------------------------------------------------------------------
# 1.9.0  skendric  02-21-2011  Upgrade to Netops 1.4.0
# 1.8.1  skendric  06-25-2010  Allow $error{$target} to be undef
# 1.8.0  skendric  03-30-2010  Upgrade to perl 5.10.1
# 1.7.0  skendric  12-23-2009  Remove Net::SNMP support
# 1.6.4  skendric  03-21-2007  Stylistic mods
# 1.6.3  skendric  11-16-2006  Replace Object Values with OIDs
# 1.6.2  skendric  09-22-2006  Change variable names
# 1.6.1  skendric  11-05-2005  Upgrade to new WI::VDOPS module structure
# 1.6.0  skendric  05-09-2005  Support Netops.pm-1.2
# 1.5.1  skendric  11-15-2004  Fiddle with report columns
# 1.5.0  skendric  05-10-2004  Migrate common functions to Netops.pm
# 1.4.0  skendric  04-30-2004  Enhance command-line options
# 1.3.3  skendric  02-02-2004  Debugging fix
# 1.3.2  skendric  11-16-2003  Use Net::Ping::External
# 1.3.1  skendric  08-10-2003  Minor bug fixes
# 1.3.0  skendric  03-16-2003  Tighted scoping, changed DEBUG to $debug
# 1.2.0  skendric  12-14-2002  Fiddled with column widths in report
# 1.1.0  skendric  11-17-2002  Added @version, improved build_target()
# 1.0.0  skendric  10-30-2002  First Version
#

# Author:  Stuart Kendrick, sbk {put at sign here} skendric {put dot here} com
#
# Source:  http://www.skendric.com/device
#
# This software is available under the GNU GENERAL PUBLIC LICENSE, see
# http://www.fsf.org/licenses/gpl.html
#

#
# This script takes the following approach:
#      -Parses the hosts table for a list of targets (or accepts a command-
#       line list)
#      -Queries a bunch of APC-specific variables
#      -Produces a report
#
#
# Requirements:
#     -The target(s) must be pingable
#
#     -The following MIB modules stashed in /opt/vdops/share/snmp/mibs,
#      or wherever it is that you store MIB modules:
#      PowerNet-MIB
#
#     -PERL modules:  the WI::Netops collection
#
#
# Assumptions:
#
#
# Tested on:
#        -APC 9606 Web/SNMP card, AP961x + AP963x Network Management Card,
#         SmartUPS, Symmetra, Silcon 
#        -perl-5.12.2
#        -net-snmp-5.6
#
#
# Instructions:
#       -Customize the script for your site:  find the 'user-configurable
#        variables' section and modify as appropriate
#       -Type "apc-chassis-status" to see the command-line options
#       -Try it out
#
#
#
# Caveats:
#
#
# Known Bugs:
#
#
# To do:
#

# Begin script

# Load modules
use strict;
use warnings;
use feature 'say';
use feature 'switch';
use Carp qw(carp cluck croak confess); 
use Data::Dumper;
use English qw( -no_match_vars );
use Getopt::Std;
use WI::Netops::APCTools 1.2.2;
use WI::Netops::HostTools 1.0.4;
use WI::Netops::NetopsTools 2.2.3;
use WI::Netops::NetopsData 1.4.0;
use WI::Netops::PingTools 1.1.7;
use WI::Netops::SNMPTools 1.5.3;
use WI::Netops::Utilities 1.4.4;

# Declare global variables
my %diagnosticSchedule;       # upsAdvTestDiagnosticSchedule
my %inputLineFailCause;       # upsAdvInputLineFailCause
my %lastDiagnosticsDate;      # upsAdvTestLastDiagnosticsDate
my %numOfBattPacks;           # upsAdvBatteryNumOfBattPacks
my %numOfBadBattPacks;        # upsAdvBatteryNumOfBadBattPacks
my %outputStatus;             # upsBasicOutputStatus

# Define global variables
$program_name = 'apc-chassis-status';
$usage = 'Usage:  apc-chassis-status -s {yes|no} [-d {integer}] [-r] [-a | -e {expr} | -f {filename} | 
target1 target2 target3 ...]';
$version = '1.9.0';


# Grab arguments
getopts('ad:e:f:rs:', \%option);
@target = @ARGV;

# Set mode
if      ($option{r})            { $mode = 'report'      }
elsif   (-t STDIN)              { $mode = 'interactive' }
else                            { $mode = 'batch'       }


##### Begin Main Program ###############################################
{

  check_args();                   # Check arguments

  read_config();                  # Read Netops config file

  compile_mibs();                 # Compile MIB files

  build_target();                 # Populate @target

  target_check();                 # Look for errors in @target

  basic_info();                   # Check for major errors

  sanity_check();                 # Check for major errors

  do_the_work();                  # Do the work

  print_report();                 # Print report

}
##### End Main Program ###############################################



########################################################################
# Do the work:  acquire image name
########################################################################
sub do_the_work {
  my %arg;               # Args for snmpGet
  my $val;               # Result of snmpGet

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print_it('Querying targets...');
  unless ($dome) {
    sleep $short;
    return 1;
  }

  # Loop through targets
  for my $target (@target) {

    # Acquire upsAdvBatteryNumOfBattPacks
    say 'Getting upsAdvBatteryNumOfBattPacks' if $debug > 2;
    $val = snmpGet({host => $target, oid => '.1.3.6.1.4.1.318.1.1.1.2.2.5.0'});
    $val //= $DASH;
    $numOfBattPacks{$target} = $val;

    # Acquire upsAdvBatteryNumOfBadBattPacks
    say 'Getting upsAdvBatteryNumOfBadBattPacks' if $debug > 2;
    $val = snmpGet({host => $target, oid => '.1.3.6.1.4.1.318.1.1.1.2.2.6.0'});
    $val //= $DASH;
    $val = $DASH if $val eq -1;
    $numOfBadBattPacks{$target} = $val;

    # Acquire upsAdvInputLineFailCause
    say 'Getting upsAdvInputLineFailCause.0' if $debug > 2;
    $val = snmpGet({host => $target, oid => '.1.3.6.1.4.1.318.1.1.1.3.2.5.0'});
    $val //= $DASH;
    $inputLineFailCause{$target} = $val;

    # Acquire upsBasicOutputStatus 
    say 'Getting upsBasicOutputStatus.0\n' if $debug > 2;
    $val = snmpGet({host => $target, oid => '.1.3.6.1.4.1.318.1.1.1.4.1.1.0'});
    $val //= $DASH;
    $outputStatus{$target} = $val;

    # Acquire upsAdvTestDiagnosticSchedule
    say 'Getting upsAdvTestDiagnosticSchedule' if $debug > 3;
    $val = snmpGet({host => $target, oid => '.1.3.6.1.4.1.318.1.1.1.7.2.1.0'});
    $val //= $DASH;
    $diagnosticSchedule{$target} = $val;

    # Acquire upsAdvTestLastDiagnosticsDate
    say 'Getting upsAdvTestLastDiagnosticsDate' if $debug > 3;
    $val = snmpGet({host => $target, oid => '.1.3.6.1.4.1.318.1.1.1.7.2.4.0'});
    $val //= $DASH;
    $lastDiagnosticsDate{$target} = $val;

    # Entertain operator
    print $BANG if $mode eq 'interactive';

  }

  # Make things look pretty
  say('') if $mode eq 'interactive';

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Tell the operator what I discovered
########################################################################
sub print_report {
  my $handle;
  my $total = @target;
  my $now = get_now();

  # If we are running in test mode, skip this routine
  unless ($dome) {
    print_it("Running in test mode, cannot print a meaningful report\n\n");
    return 1;
  }

  # Debug trace
  trace_location('begin') if $debug;

  # Direct output to screen or to file
  if ($mode eq 'interactive') {
    $handle = *STDOUT;
  }
  else {
    open $handle, '>', $report_file or die "Cannot open $report_file: $!\n";
  }


print {$handle} <<EOF;
#
# Title:           UPS Chassis Status Summary
#
# Institution:     $institution
#
# Date of Report:  $now
#
# Description:     This report describes the status of UPS chassis'
#
# Active:          $total
#
# Questions:       If you have questions or comments regarding this
#                  report, please mail them to $report_queries
#
# Notes:
#
# ups status = unknown, onLine, onBattery, onSmartBoost, timedSleeping, 
#              softwareBypass, off, rebooting, switchedBypass, 
#              hardwareFailureBypass, sleepingUntilPowerReturn, or onSmartTrim
#
# lineFailCause = The most recent reason why the UPS transferred to battery:
#                 noTransfer, highLineVoltage, brownout, blackout, 
#                 smallMomentarySag, deepMomentarySag, smallMomentarySpike, 
#                 largeMomentarySpike, selfTest, rateOfVoltageChange
#
# schedule = Schedule on which the UPS performs its self test
#
# date     = Date on which the UPS last performed its self test
#
# #        = Number of battery packs installed
#
# # bad    = Number of bad battery packs
#
#
target        ups                 lineFail            schedule date       #   #
              status              Cause                                      bad
------------- ------------------- ------------------- -------- ---------- -- ---
EOF
  for my $target (@target) {
    printf {$handle} "%-13s %-19.19s %-19.19s %-8.8s %-10.10s %2s %3s\n",
      $target, $outputStatus{$target}, $inputLineFailCause{$target}, 
      $diagnosticSchedule{$target}, $lastDiagnosticsDate{$target}, 
      $numOfBattPacks{$target}, $numOfBadBattPacks{$target};
  }
  unless ($handle =~ /STDOUT/) {
    close $handle or warn "Cannot close $report_file: $!\n";
  }

  # Make things look pretty
  log_it("Ending $PROGRAM_NAME");
  say "Ending $PROGRAM_NAME" if $mode eq 'interactive';

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Sanity check
########################################################################
sub sanity_check {
  my @remove;

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print_it('Sanity check...');

  # Loop through targets, removing non-APC devices
  TARGET:
  for my $target (@target) {
  
    # Identify manufacturer
    unless ($manufacturer{$target} eq 'APC') {
      print_it("\nManufacturer of $target is not APC, ignoring\n");
      push @remove, $target;
      next TARGET;
    }

    # Identify UPS model
    if ($apc_device_model{$target} eq 'unknown') {
      print_it("\nCannot determine UPS model of $target, ignoring");
      push @remove, $target;
      next;
    }

    # Entertain operator
    print $BANG if $mode eq 'interactive';

  }

  # Make things look pretty
  print "\n\n" if $mode eq 'interactive';

  # Remove entries which failed checks
  prune_basic(@remove);

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Output help
########################################################################
sub HELP_MESSAGE {
  print <<EOF;

  See $netops_global_config (and $netops_alarm_config if this is an
  xxxx-alarm script) for configuration options

  $usage

    -s asks the question:  are you serious?  If you answer 'no', then 
       the script will run in demo mode, making no changes

    -d specifies debug level (typically 0-9)

    -r determines whether or not the script writes its report to disk

    -a instructs the script to filter the hosts table using its internally
       defined suffixes variable to produce a list of targets

    -e requires a regex as its argument, with which the script filters
       the hosts table to produce a list of targets.  Enclose the regex in 
       quotes to protect special characters from the shell

    -f points the script to a file containing the list of targets

    target1 target2 target3 ... is the command-line list of targets you
      have specified, in lieu of the -a, -e, or -f options

EOF

  return 1;
}




########################################################################
# Output version
########################################################################
sub VERSION_MESSAGE {
  say "$program_name v$version";
  return 1;
}