#!/opt/vdops/bin/perl

# This script reports information about the hardware underneath UPSes

# V      Who       When        What
# ---------------------------------------------------------------------------
# 1.8.0  skendric  02-21-2011  Upgrade to Netops 1.4.0
# 1.7.0  skendric  02-01-2010  Migrate mgmt card details to apc-mgmt-card
# 1.6.0  skendric  12-23-2009  Remove Net::SNMP support
# 1.5.5  skendric  05-20-2008  Fiddle with report format
# 1.5.4  skendric  03-21-2008  Add support for PDUs
# 1.5.3  skendric  11-16-2006  Replace Object Values with OIDs
# 1.5.2  skendric  09-22-2006  Change variable names
# 1.5.1  skendric  11-05-2005  Upgrade to new WI::VDOPS module structure
# 1.5.0  skendric  05-09-2005  Support Netops.pm-1.2
# 1.4.1  skendric  11-15-2004  Add support for new Symmetras
# 1.4.0  skendric  05-10-2004  Migrate common functions to Netops.pm
# 1.3.0  skendric  04-30-2004  Enhance command-line options
# 1.2.3  skendric  02-02-2004  Add support for AP961x
# 1.2.2  skendric  11-16-2003  Use Net::Ping::External
# 1.2.1  skendric  08-10-2003  Minor bug fixes
# 1.2.0  skendric  03-16-2003  Tighted scoping, changed DEBUG to $debug
# 1.1.0  skendric  11-17-2002  Added @version, improved build_target()
# 1.0.0  skendric  10-22-2002  First Version
#

# Author:  Stuart Kendrick, sbk {put at sign here} skendric {put dot here} com
#
# Source:  http://www.skendric.com/device
#
# This software is available under the GNU GENERAL PUBLIC LICENSE, see
# http://www.fsf.org/licenses/gpl.html
#

#
# This script takes the following approach:
#      -Parses the hosts table for a list of targets (or accepts a command-
#       line list)
#      -Queries sysDescr and a bunch of APC-specific variables
#      -Produces a report
#
#
# Requirements:
#     -The target(s) must be pingable
#
#     -The following MIB modules stashed in /opt/vdops/share/snmp/mibs,
#      or wherever it is that you store MIB modules:
#      PowerNet-MIB
#
#     -PERL modules:  the WI::Netops collection
#
#
# Assumptions:
#
#
# Tested on:
#        -APC 9606 Web/SNMP card, AP961x + AP963x Network Management Card,
#         SmartUPS, Symmetra, Silcon 
#        -perl-5.12.2
#        -net-snmp-5.6
#
#
# Instructions:
#       -Customize the script for your site:  find the 'user-configurable
#        variables' section and modify as appropriate
#       -Type "apc-hardware" to see the command-line options
#       -Try it out
#
#
#
# Caveats:
#
#
# Known Bugs:
#
#
# To do:
#

# Begin script

# Load modules
use strict;
use warnings;
use feature 'say';
use feature 'switch';
use Carp qw(carp cluck croak confess); 
use Data::Dumper;
use English qw( -no_match_vars );
use Getopt::Std;
use List::MoreUtils qw(uniq);;
use WI::Netops::APCTools 1.2.2;
use WI::Netops::HostTools 1.0.4;
use WI::Netops::NetopsTools 2.2.3;
use WI::Netops::NetopsData 1.4.0;
use WI::Netops::PingTools 1.1.7;
use WI::Netops::SNMPTools 1.5.3;
use WI::Netops::Utilities 1.4.4;

# Declare global variables
my %date;                   # manufacturing date
my %firmware;               # firmware revision
my %model;                  # Hacked version of %apc_device_model
my %serial;                 # serial number

# Define global variables
$program_name = 'apc-hardware';
$usage = 'Usage:  apc-hardware -s {yes|no} [-d {integer}] [-r] [-a | -e {expr} | -f {filename} | 
target1 target2 target3 ...]';
$version = '1.8.0';


# Grab arguments
getopts('ad:e:f:rs:', \%option);
@target = @ARGV;

# Set mode
if      ($option{r})            { $mode = 'report'      }
elsif   (-t STDIN)              { $mode = 'interactive' }
else                            { $mode = 'batch'       }


##### Begin Main Program ###############################################
{

  check_args();                   # Check arguments

  read_config();                  # Read Netops config file

  compile_mibs();                 # Compile MIB files

  build_target();                 # Populate @target

  target_check();                 # Look for errors in @target

  basic_info();                   # Gather information

  sanity_check();                 # Check for major errors

  do_the_work();                  # Do the work

  print_report();                 # Print report

}
##### End Main Program ###############################################



########################################################################
# Do the work:  acquire image name
########################################################################
sub do_the_work {
  my %arg;               # Args for snmpGet
  my $val;               # Result of snmpGet

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print_it('Parsing sysDescr and querying variables...');
  unless ($dome) {
    sleep $short;
    return 1;
  }

  # Loop through targets
  for my $target (@target) {

    # Debug info
    say "  Parsing $target" if $debug;

    # Shrink model
    my $model = $apc_device_model{$target};
    given ($model) {
      when (/Battery/) {
        $model = 'BMS';
      }
      when (/Environmental Manager/) {
        ($model = $model) =~ s/ Main Module//;
      }
      when (/Environmental Monitor/) {
        ($model = $model) =~ s/Monitoring Unit/Monitor/;
      }
      when (/NetBotz/) {
        ($model = $model) =~ s/Rack Monitor //;
      }
    }
    $model{$target} = $model;

    # Acquire firmware revision
    $firmware{$target} = acquire_apc_firmware($target);

    # Acquire manufacture date
    $date{$target} = acquire_apc_manufacture_date($target);

    # Acquire serial number
    $serial{$target} = acquire_apc_serial_number($target);

    # Entertain operator
    print $BANG if $mode eq 'interactive';

  }

  # Make things look pretty
  say('') if $mode eq 'interactive';

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Tell the operator what I discovered
########################################################################
sub print_report {
  my $handle;
  my @models;            # Values extracted from %models
  my $now = get_now();
  my $total = @target;

  # If we are running in test mode, skip this routine
  unless ($dome) {
    print_it("Running in test mode, cannot print a meaningful report\n");
    return 1;
  }

  # Debug trace
  trace_location('begin') if $debug;

  # Direct output to screen or to file
  if ($mode eq 'interactive') {
    $handle = *STDOUT;
  }
  else {
    open $handle, '>', $report_file or die "Cannot open $report_file: $!\n";
  }


print {$handle} <<EOF;
#
# Title:           APC Hardware Report
#
# Institution:     $institution
#
# Date of Report:  $now
#
# Description:     This report describes the hardware underneath APC devices
#
# Active:          $total
#
# Questions:       If you have questions or comments regarding this
#                  report, please mail them to $report_queries
#
# Notes:
#
# Device   = Underlying APC host
# Firmware = Firmware Revision
# Serial   = Serial Number
# Date     = Manufacturing Date
#
target            Device                   Firmware   Serial         Date
----------------- ------------------------ ---------- -------------- ----------
EOF

  # Sort by model
  for my $model (uniq sort values %model) {

    # Pick targets which fit this model
    TARGET:
    for my $target (@target) {
      next TARGET unless $model{$target} eq $model;
      printf {$handle} "%-17s %-24s %-10s %-14s %-10s\n",
             $target, $model{$target}, $firmware{$target}, 
             $serial{$target}, $date{$target}, 
    }

  }
  unless ($handle =~ /STDOUT/) {
    close $handle or warn "Cannot close $report_file: $!\n";
  }

  # Make things look pretty
  log_it("Ending $PROGRAM_NAME");
  say "Ending $PROGRAM_NAME" if $mode eq 'interactive';

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Sanity check
########################################################################
sub sanity_check {
  my @remove;

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print_it('Sanity check...');

  # Loop through targets, removing non-APC devices
  SANITY:
  for my $target (@target) {
  
    # Identify manufacturer
    unless ($manufacturer{$target} eq 'APC') {
      say "\nManufacturer of $target is not APC, ignoring" if $debug;
      push @remove, $target;
      next SANITY;
    }

    # Identify UPS model
    if ($apc_device_model{$target} eq 'unknown') {
      say "\nCannot determine model of $target, ignoring" if $debug;
      push @remove, $target;
      next SANITY;
    }

    # Entertain operator
    print $BANG if $mode eq 'interactive';

  }

  # Make things look pretty
  print "\n\n" if $mode eq 'interactive';

  # Remove entries which failed checks
  prune_basic(@remove);

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Output help
########################################################################
sub HELP_MESSAGE {
  print <<EOF;

  See $netops_global_config (and $netops_alarm_config if this is an
  xxxx-alarm script) for configuration options

  $usage

    -s asks the question:  are you serious?  If you answer 'no', then 
       the script will run in demo mode, making no changes

    -d specifies debug level (typically 0-9)

    -r determines whether or not the script writes its report to disk

    -a instructs the script to filter the hosts table using its internally
       defined suffixes variable to produce a list of targets

    -e requires a regex as its argument, with which the script filters
       the hosts table to produce a list of targets.  Enclose the regex in 
       quotes to protect special characters from the shell

    -f points the script to a file containing the list of targets

    target1 target2 target3 ... is the command-line list of targets you
      have specified, in lieu of the -a, -e, or -f options

EOF

  return 1;
}




########################################################################
# Output version
########################################################################
sub VERSION_MESSAGE {
  say "$program_name v$version";
  return 1;
}