#!/opt/vdops/bin/perl

# This script automates the process of setting variables in UPSes

# V      Who       When        What
# ---------------------------------------------------------------------------
# 1.7.0  skendric  02-21-2011  Upgrade to Netops 1.4.0
# 1.6.1  skendric  06-25-2010  Allow $error{$target} to be undef
# 1.6.0  skendric  03-30-2010  Upgrade to perl 5.10.1
# 1.5.5  skendric  12-31-2008  Support new snmpSet format
# 1.5.4  skendric  03-21-2007  Stylistic mods
# 1.5.3  skendric  11-16-2006  Replace Object Values with OIDs
# 1.5.2  skendric  09-22-2006  Change variable names
# 1.5.1  skendric  11-05-2005  Upgrade to new WI::VDOPS module structure
# 1.5.0  skendric  05-09-2005  Support Netops.pm-1.2
# 1.4.1  skendric  05-19-2004  Fix bug in acquring/setting time
# 1.4.0  skendric  05-10-2004  Migrate common functions to Netops.pm
# 1.3.0  skendric  04-30-2004  Enhance command-line options
# 1.2.3  skendric  02-02-2004  Documentation fixes
# 1.2.2  skendric  11-16-2003  Use Net::Ping::External
# 1.2.1  skendric  08-10-2003  Minor bug fixes
# 1.2.0  skendric  03-16-2003  Tighted scoping, changed DEBUG to $debug
# 1.1.1  skendric  12-12-2002  Fixed write string bug in info_before
# 1.1.0  skendric  11-17-2002  Added @version, improved build_target()
# 1.0.0  skendric  10-22-2002  First Version
#

# Author:  Stuart Kendrick, sbk {put at sign here} skendric {put dot here} com
#
# Source:  http://www.skendric.com/device
#
# This software is available under the GNU GENERAL PUBLIC LICENSE, see
# http://www.fsf.org/licenses/gpl.html
#

#
# This script takes the following approach:
#       -Parses the hosts table for a list of targets (or accepts a command-
#        line list)
#       -Sets name, date, and time
#
# Requirements:
#     -The target(s) must be pingable
#
#     -The following MIB modules stashed in /opt/vdops/share/snmp/mibs,
#      or wherever it is that you store MIB modules:
#      PowerNet-MIB
#
#     -PERL modules:  the WI::Netops collection
#
#
#
# Assumptions:
#
#
# Tested on: 
#        -APC 9606 Web/SNMP card, AP961x + AP963x Network Management Card
#        -perl-5.12.2
#        -net-snmp-5.6
#
#
# Instructions:
#       -Customize the script for your site:  find the 'user-configurable
#        variables' section and modify as appropriate
#       -Type "apc-set-stuff" to see the command-line options
#       -Try it out
#
#
# Caveats:
#
#
# Known Bugs:
#
#
# To do:
#     -Test username/password foo
#

# Begin script

# Load modules
use strict;
use warnings;
use feature 'say';
use feature 'switch';
use Carp qw(carp cluck croak confess); 
use Data::Dumper;
use DateTime;
use English qw( -no_match_vars );
use Getopt::Std;
use WI::Netops::APCTools 1.2.2;
use WI::Netops::HostTools 1.0.4;
use WI::Netops::NetopsTools 2.2.3;
use WI::Netops::NetopsData 1.4.0;
use WI::Netops::PingTools 1.1.7;
use WI::Netops::SNMPTools 1.5.3;
use WI::Netops::Utilities 1.4.4;

# Declare global variables

# Define global variables
$program_name = 'apc-set-stuff';
$usage = 'Usage:  apc-set-stuff -s {yes|no} [-d {integer}] [-r] [-a | -e {expr} | -f {filename} | target1 target2 target3 ...]';
$version = '1.7.0';


# Grab arguments
getopts('ad:e:f:s:', \%option);
@target = @ARGV;

# Set mode
if      ($option{r})            { $mode = 'report'      }
elsif   (-t STDIN)              { $mode = 'interactive' }
else                            { $mode = 'batch'       }


### Begin Main Program ###############################################
{

  check_args();                   # Check arguments

  read_config();                  # Read Netops config file

  compile_mibs();                 # Compile MIB files

  build_target();                 # Populate @target

  target_check();                 # Look for errors in @target

  basic_info();                   # Gather information

  sanity_check();                 # Check for major errors

  print_before();                 # Tell operator what I will do

  do_the_work();                  # Set variables

  info_after();                   # Gather information

  print_after();                  # Tell the operator what I did

}
##### End Main Program ###############################################


########################################################################
# Do the work
########################################################################
sub do_the_work {

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  say 'Setting variables...' if $mode eq 'interactive';

  # Loop through @target, setting various variables
  for my $target (@target) {
    my ($dt, $date, $time, $val, @varbind);

    # Define time
    $dt = DateTime->now( time_zone => 'local' );
    $date = $dt->mdy($DASH);
    $time = $dt->hms;

    # Add date
    push @varbind,
                  'mconfigClockDate',
                   0,
                   $date,
                  'OCTETSTR';

    # Add time
    push @varbind,
                  'mconfigClockTime',
                   0,
                   $time,
                  'OCTETSTR';

    # Add name
    given ($target) {
      when (/\-bat/) {
        say "Setting experimental.94.1.6.1.20.1 to $target" if $debug > 3;
        push @varbind,
                      '.1.3.6.1.4.1.318.1.4.94.1.6.1.20',
                       1,
                      $target,
                      'OCTETSTR';
      }
      when (/\-emu/) {
        push @varbind,
                      'emsIdentEMSName',
                       0,
                       $target,
                     'OCTETSTR';
      }
      when (/\-pdu/) {
        push @varbind,
                      'rPDUIdentName',
                       0,
                      $target,
                      'OCTETSTR';
      }
      when (/\-ups/) {
        push @varbind,
                      'upsBasicIdentName',
                       0,
                       $target,
                      'OCTETSTR';
      }
    }

    # Perform the set
    if ($dome) {
      $val = snmpSet( {host => $target, varbind => \@varbind} );
      given ($val) {
        when (undef) { say "  Failed on $target"    }
        default      { say "  Succeeded on $target" }
      }
    }
    else {
      say "  Just kidding for $target";
    }
      
  }

  # Make things look pretty
  say "\n" if $mode eq 'interactive';

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Gather information after file uploads
########################################################################
sub info_after {

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print_it('Pinging targets...');

  # If we are running in test mode, pause briefly, then return
  unless ($dome) {
    sleep $short;
    return 1;
  }

  # Loop through targets, gathering file information
  for my $target (@target) {

    # If we can't ping the target, skip to the next one
    unless (ping_it($target)) {
      print_it("\nCannot ping $target");
      $error{$target} .= 'Cannot ping  ';
    }

  }

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Tell operator what I did
########################################################################
sub print_after {
  my $shit_happens = 0;

  # Debug trace
  trace_location('begin') if $debug;

  # If running from cron, don't print report
  return 1 if $mode eq 'batch';

  say "\n\n# Here is what I see";

  # If we are running in test mode, then return
  unless ($dome) {
    print "Running in test mode, cannot print a meaningful report\n\n";
    return 1;
  }

  # Iterate through @target
  for my $target (@target) {
    log_it("Set variables on $target") if $dome;
    $shit_happens++ if defined $error{$target};
  }

  return 1 unless $mode eq 'interactive';

  # Congratulate operator
  say "\n\nDone setting variables";

print "\n";
print <<EOF;
#
# Current targets look like this
#
# target            Network Card  Device
------------------  ------------  ------------------------------
EOF

  for my $target (@target) {
    printf "%-18s  %-12s  %-30s\n",
            $target, $apc_card_model{$target}, $apc_device_model{$target};
  }
  say('');

  # If an error occured, talk about it
  if ($shit_happens > 0) {
      print "\n\n\n\n";
      print <<EOF;
#
# Here are the problems I encountered.  I'm not smart enough to fix
# these; please handle these yourself
#
# target            warning message(s)
------------------  --------------------------------------------------
EOF
    for my $target (@target) {
      if (defined $error{$target}) {
        printf "%-18s  %-60s\n", $target, $error{$target};
        log_it("Errors for $target:  $error{$target}");
      }
    }
  }
  say('');

  # Make things look pretty
  log_it("Ending $PROGRAM_NAME");
  say "Ending $PROGRAM_NAME" if $mode eq 'interactive';

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Tell the operator what I will do
########################################################################
sub print_before {

  # Debug trace
  trace_location('begin') if $debug;

  # If running from cron, don't print report
  return 1 if $mode eq 'batch';

print "\n";
print <<EOF;
#
# Current targets look like this
#
# target              Network Card  Device
# ------------------  ------------  ------------------------------
EOF

  for my $target (@target) {
    printf "# %-18s  %-12s  %-30s\n",
            $target, $apc_card_model{$target}, $apc_device_model{$target};
  }
  say "#";

  say('');
  say('');
  say 'Setting variables:';
  say 'I plan to set name, date, and time on these devices';
  say('');
  if ($dome) {
    say 'This is the real thing:  I will set variables';
  }
  else {
    say 'This is a dry run, no variables will be set';
  }
  say "Stalling for $long seconds to give you time to cancel ...\n";
  sleep $long;
  say "OK, let's roll\n";

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Sanity check
########################################################################
sub sanity_check {
  my @remove;

  # Debug trace
  trace_location('begin') if $debug;

  # Notify operator
  print_it('Sanity check...');

  # Loop through targets, removing non-APC devices
  SANITY:
  for my $target (@target) {
  
    # Identify manufacturer
    unless ($manufacturer{$target} eq "APC") {
      say "\nManufacturer of $target is not APC, ignoring" if $debug;
      push @remove, $target;
      next SANITY;
    }

    # Entertain operator
    print $BANG if $mode eq 'interactive';

  }

  # Make things look pretty
  say('') if $mode eq 'interactive';

  # Remove entries which failed checks
  prune_basic(@remove);

  # Debug trace
  trace_location('end') if $debug;

  return 1;
}




########################################################################
# Output help
########################################################################
sub HELP_MESSAGE {
  print <<EOF;

  See $netops_global_config (and $netops_alarm_config if this is an
  xxxx-alarm script) for configuration options

  $usage

    -s asks the question:  are you serious?  If you answer 'no', then 
       the script will run in demo mode, making no changes

    -d specifies debug level (typically 0-9)

    -a instructs the script to filter the hosts table using its internally
       defined suffixes variable to produce a list of targets

    -e requires a regex as its argument, with which the script filters
       the hosts table to produce a list of targets.  Enclose the regex in 
       quotes to protect special characters from the shell

    -f points the script to a file containing the list of targets

    target1 target2 target3 ... is the command-line list of targets you
      have specified, in lieu of the -a, -e, or -f options

EOF

  return 1;
}




########################################################################
# Output version
########################################################################
sub VERSION_MESSAGE {
  say "$program_name v$version";
  return 1;
}